User:Dart Raiden/Build Miranda

You need to install Strawberry Perl and NASM to build OpenSSL.

It is assumed that you have 7-Zip, TortoiseGit, and Visual Studion 2017 installed.

build.bat:

@echo off

:CheckAdminRights
net session >nul 2>&1
if not %ErrorLevel% == 0 (
	echo Please run as administator^^!
	pause
	exit /b 1
)

:SetVariables
set "unpacker=%ProgramFiles%\7-Zip\7zG.exe"
set "Configuration=Release"
set "Miranda=%ProgramFiles%\Miranda NG"
set "Vs=%ProgramFiles(x86)%\Microsoft Visual Studio\2017\Community"
set "Msbuild=%Vs%\MSBuild\15.0\Bin\MSBuild.exe"
set "Openssl=D:\dev\openssl"
set "Path=%ProgramFiles%\NASM;%Path%"
set "Solution=bin15"
set "Sources=D:\dev\miranda-ng"

:CleanSources
if exist "%sources%\%Solution%\%configuration%64" rd /s /q "%sources%\%Solution%\%configuration%64"
cd /d "%sources%"
call cleaner.bat

:UpdateSources
tortoisegitproc /command:pull /path:"%sources%"

:SetVsEnvironmentVariables
call "%vs%\Common7\Tools\vsdevcmd.bat" -arch=amd64 -host_arch=amd64 -no_logo

:BuildTdlib
"%msbuild%" "%sources%\%Solution%\tdlib.sln" /m /t:Rebuild /p:Configuration=Release /p:Platform=x64
if not %ErrorLevel% == 0 (
	echo ********** TDLib build failed **********
	pause
	exit /b 1
)

:BuildMiranda
"%msbuild%" "%sources%\%Solution%\my.sln" /m /t:Rebuild /p:Configuration=Release /p:Platform=x64
if not %ErrorLevel% == 0 (
	echo ********** Miranda build failed **********
	pause
	exit /b 1
)

:BuildIcons
"%msbuild%" "%sources%\%Solution%\my_icons.sln" /m /t:Rebuild /p:Configuration=Release /p:Platform=x64
if not %ErrorLevel% == 0 (
	echo ********** Icons build failed **********
	pause
	exit /b 1
)

:BuildLangpack
mkdir "%sources%\%Solution%\%configuration%64\Languages"
cscript /nologo "%sources%\tools\lpgen\translate.js" /sourcelang:"russian" /release:"%sources%\%Solution%\%configuration%64\Languages\langpack_russian.txt"

:SortCompiledFiles
cd /d "%sources%\%Solution%\%configuration%64"
rd /q /s Obj
for /r %%i in (*.ilk,*.iobj,*.ipdb) do del /q /s %%i
for /r Icons %%j in (*.pdb) do del /q /s %%j
for /r %%k in (*.pdb) do move %%k "%sources%\%Solution%\%configuration%64"

:KillMiranda
Taskkill /f /im Miranda64.exe

:BackupOldMiranda
if exist "%Temp%\Miranda_backup" rd /q /s "%Temp%\Miranda_backup"
xcopy /i /s /y "%Miranda%" "%Temp%\Miranda_backup"

:UpdateMiranda
xcopy /i /s /y "%sources%\%Solution%\%configuration%64" "%Miranda%"

:BuildOpenssl
cd /d "%Openssl%"
git apply "%Sources%\tools\openssl\openssl-mir-changes.patch"
perl "%Openssl%\Configure" shared VC-WIN64A
nmake
for %%n in (libcrypto-1_1.mir,libssl-1_1.mir) do xcopy /y %%n "%Miranda%\Libs"
for %%n in (libcrypto-1_1.pdb,libssl-1_1.pdb) do xcopy /y %%n "%Miranda%"

:RunMiranda
:: dirty hack to prevent the app from inheriting elevated permissions
explorer "%Miranda%\Miranda64"

exit /b 0

my.sln and my_icons.sln are my custom solutions.