User:Dart Raiden/Build Miranda

From Miranda NG
Jump to navigation Jump to search

start.bat:

@echo off

start /wait elevate -c -w build.bat
exit

build.bat:

@echo off

set sources=D:\dev\miranda-ng
set solution_dir=bin15
set configuration=Release
set miranda_path=%PROGRAMFILES%\Miranda NG
set vspath=%PROGRAMFILES(X86)%\Microsoft Visual Studio\2017\Community
set msbuild=%vspath%\MSBuild\15.0\Bin\MSBuild.exe

:set_vs_variables
call "%vspath%\Common7\Tools\vsdevcmd.bat" -arch=amd64 -host_arch=amd64 -no_logo -vcvars_spectre_libs=spectre

:clean_old_build
cd /d "%sources%\%solution_dir%"
if exist "%sources%\%solution_dir%\%configuration%64" rd /q /s "%sources%\%solution_dir%\%configuration%64" >nul
if exist "%sources%\include\m_version.h" del /q /s "%sources%\include\m_version.h"
call "%sources%\cleaner.bat"

:update_sources
call TortoiseGitProc /command:pull /path:"%sources%"

:build_miranda
call "%msbuild%" %sources%\%solution_dir%\my.sln /m /t:Rebuild /p:Configuration=Release /p:Platform=x64
if errorlevel 1 (
echo ********** MIRANDA BUILD FAIL **********
pause
exit )

:build_icons
call "%msbuild%" %sources%\%solution_dir%\my_icons.sln /m /t:Rebuild /p:Configuration=Release /p:Platform=x64
if errorlevel 1 (
echo ********** ICONS BUILD FAIL **********
pause
exit )

:sort
cd /d "%sources%\%solution_dir%\%configuration%64"
rd /q /s "%sources%\%solution_dir%\%configuration%64\Obj" >nul
for /r "%sources%\%solution_dir%\%configuration%64" %%i in (*.ilk,*.iobj,*.ipdb) do del /q /s %%i >nul
for /r "%sources%\%solution_dir%\%configuration%64\Icons" %%j in (*.pdb) do del /q /s %%j >nul
for /r "%sources%\%solution_dir%\%configuration%64" %%k in (*.pdb) do move %%k "%sources%\%solution_dir%\%configuration%64" >nul

:kill
Taskkill /f /im Miranda64.exe
timeout 3

:backup
if exist "%miranda_path%\Plugin Updates\Backups" rd /q /s "%miranda_path%\Plugin Updates\Backups" >nul
if exist "%TEMP%\Miranda_backup" rd /q /s "%TEMP%\Miranda_backup" >nul
xcopy /i /s /y "%miranda_path%" "%TEMP%\Miranda_backup" >nul

:replace
cd /d "%sources%\%solution_dir%\%configuration%64"
for %%l in (exe,mir,pdb) do del /q /s "%miranda_path%\*.%%l" >nul
for %%m in (Core,Icons,Plugins) do rd /q /s "%miranda_path%\%%m" >nul
xcopy /i /s /y "%sources%\%solution_dir%\%configuration%64" "%miranda_path%" >nul
for %%n in (libeay32.mir,ssleay32.mir) do xcopy /y "%TEMP%\Miranda_backup\Libs\%%n" "%miranda_path%\Libs" >nul
for %%o in (libeay32.pdb,ssleay32.pdb) do xcopy /y "%TEMP%\Miranda_backup\%%o" "%miranda_path%" >nul

:clean
cd /d "%sources%\%solution_dir%"
if exist "%sources%\%solution_dir%\%configuration%64" rd /q /s "%sources%\%solution_dir%\%configuration%64" >nul
if exist "%sources%\include\m_version.h" del /q /s "%sources%\include\m_version.h"

:run
runas /trustlevel:0x20000 "%miranda_path%\Miranda64.exe"

exit

Here you can download elevate utility. my.sln and my_icons.sln are my custom solutions.